Syntax

register chunk generator with id %string%

Description

Register a chunk generator to manipulate the world layout to your liking. **ENTRIES**: (These are all optional, and will default to false) - `vanilla decor` = Whether Minecraft will decorate the surface based on biomes. - `vanilla caves` = Whether Minecraft will carve caves. - `vanilla structures` = Whether Minecraft will generate structures based on biomes. - `vanilla mobs` = Whether Minecraft will spawn mobs based on biomes. **SECTIONS**: (These are all optional) - `noise gen` = Generate the base terrain of a chunk [optional, defaults to vanilla noise]. - `surface gen` = Generate the surface above the base terrain of the chunk [optional, defaults to vanilla surface]. - `chunk gen` = A combination of noise and surface gen (Cannot be used WITH noise/surface gen). - `cave gen` = Generate caves in a chunk [optional]. - `biome gen` = Generate the biomes to be placed in a chunk [optional, will default to vanilla biomes]. - `height gen` = Tell Minecraft where the highest block in a chunk is for generating structures. - `block pop` = Used to decorate after initial surface is generated (Structures can be placed during this stage). **NOTES**: - `world-creator` needs to be enabled in the config - Please see the [**Chunk Generator**](https://github.com/ShaneBeee/SkBee/wiki/Chunk-Generator) wiki for further details.

Examples

register chunk generator with id "mars":
	vanilla decor: false
	vanilla caves: false
	vanilla structures: false
	vanilla mobs: false
	chunk gen:
		loop integers between 0 and 15:
			loop integers between 0 and 15:
				set {_x} to (loop-number-1)
				set {_z} to (loop-number-2)

				# This is just an expression I created with reflect to give you an idea how it can work
				set {_y} to biome noise at vector({_x} + (chunkdata chunk x * 16), 1, {_z} + (chunkdata chunk z * 16))
				# Fill blocks from 0 to y level with concrete
				set chunkdata blocks within vector({_x}, 0, {_z}) and vector({_x}, {_y}, {_z}) to red_concrete[]
				# Set the surface layer to concrete powder
				set chunkdata block at vector({_x}, {_y}, {_z}) to red_concrete_powder[]

	biome gen:
		# Set our biome to something mars like
		set chunkdata biome to crimson forest